Bilag F - Dansk linjeformat for udveksling af bibliografiske poster

Udarbejdet af Dansk Standards Udvalg for Information og Dokumentation. Anvendelse af Informationsteknologi.

1. Formål

At fastlægge en standard (linjeformatet) for repræsentation af bibliografiske poster i tekstfiler - til brug for udveksling mellem danske biblioteker. Standarden er et alternativ til DS/ISO 2709 til udveksling af danMARC2-formaterede poster.

Dette indebærer, at der for danMARC2-formaterede poster skal kunne konverteres mellem linjeformatet og DS/ISO 2709.

2. Referencer

DS/ISO 646
DS/ISO 2709
DS/ISO 8859-1
DS/ISO/IEC 10646-1
Unicode (DS/ISO/IEC 10646-1)

3. Definitioner

Jævnfør DS/ISO 2709 med følgende tilføjelser:

Tekstfil

Afsluttet maskinlæsbar enhed bestående af grafiske tegn kodet i henhold til det grundlæggende tegnsæt. Ved at fortolke visse af de kodede værdier som skiftekoder kan principielt alle tegn i referencetegnsættet samt øvrige specialtegn repræsenteres.

Tegnrepetoire

Det grundlæggende tegnsæt er ISO 8859-1, men alle tegn fra unicode kan angives ved brug af skiftekode, se bilag K.

Kontroltegn

Anvendelsen af kontroltegn sker i henhold til DS/ISO 646.

4. Generel struktur af tekstfil med bibliografiske poster

Posterne forefindes i tekstfil, opdelt i linjer på maksimalt 79 tegn efterfulgt af linjeafslutning. Posterne er adskilt af tegnet "$". Postens felter kan anføres i vilkårlig rækkefølge. Hvert felt starter på en ny linje, og optager så mange linjer som der er behov for, idet efterfølgende linjer indledes med 4 blanktegn. Linjedeling kan ske når som helst. Alle tegn er signifikante - også blanktegn i slutningen af en linje.

I nedenstående syntaks er terminale elementer direkte anført med sin hexadecimale værdi (med foranstillet x) eller grafiske repræsentation fra det grundlæggende tegnsæt. Nonterminale elementer er markeret med tegnene <>.

Elementer som kan gentages er omgivet af tegnene ( og ) - samt tilføjet specifikation af nedre og øvre grænse for antallet af forekomster. Hvis der ikke er fastlagt en øvre grænse anføres tegnet *. Hvis øvre og nedre grænse er identisk anføres kun én værdi.

Hvis der kan vælges mellem flere elementer adskilles disse med tegnet |.

Tegnet / betegner at det efterfølgende er en kommentar.

<tekstfil>::=	(<post>) 1-*
<post>::=	(<felt>) 1-* <postslut>
<felt>::=	<feltkode><blank>(<indikator>) 2 <blank><tekst><linjeslut> ((<blank>) 4 <suppl. tekst><linjeslut>) 0-*
<postslut>::=	$<linjeslut>
<linjeslut>::=	x0D x0A | x0A /CR LF eller bare LF
<feltkode>::=	(<grafisk tegn>) 3 /gangbare feltkoder er fastlagt i danMARC2
<blank>::=	x20 /SP
<indikator>::=	<grafisk tegn> /gangbare værdier er fastlagt i danMARC2
<tekst>::=	(<grafisk tegn>) 0-72
<suppl. tekst>::=	(<grafisk tegn>) 0-75

 

Kommentarer:

Alle felter er opbygget ens. Hvis man konkatenerer <tekst> og efterfølgende <suppl. tekst> fremstår datadelen <feltdata>, som er opbygget af delfelter efter følgende princip:

<feltdata>::=	(<delfelt>) 1-*
<delfelt>::=	<skilletegn><delfeltkode><delfeltdata>
<skilletegn>::=	*
<delfeltkode>::=	<grafisk tegn> /gangbare værdier er fastlagt i danMARC2
<delfeltdata>::=	(<grafisk tegn>) 0-*
<grafisk tegn>::=	x20 | ... | x7E | xA0 | ... | xFF